<%@ LANGUAGE=VBScript %>
<%
Option Explicit
%>
<!DOCTYPE HTML PUBLIC '-//W3C//DTD HTML 4.0 Transitional//EN'>
<html>
<head>
<meta http-equiv='Content-Type' content='text/html;charset=Shift_JIS'>
<meta name="robots" content="noindex,nofollow">
<meta http-equiv='expires' content='0'>
</head>
<body>
<%
Dim w_FileName, w_Scr, w_Path, w_FS, w_F, w_TXT
'ソースファイルのファイル名(相対パス)を受け取る
w_FileName = Request("filename")
If InStr(w_FileName,"..") Then
    Response.Write "参照は許可されていません。<br>" & vbCrLf
Else
    If w_FileName <> "" Then
        w_Scr = "scripting.fileSystemObject"
        Set w_FS = server.CreateObject(w_Scr)
        'カレントのパスを取得
        w_Path = server.mapPath(".")
        'ソースファイルのパスを編集
        w_Path = w_Path & "\" & w_FileName
        On Error Resume Next
        'ソースファイルを開く
        Set w_F = w_FS.openTextFile(w_Path)
        If Err <> 0 Then
            Response.Write "ファイルが見つかりません。<br>" & vbCrLf
            Response.Write "ファイル名:" & w_FileName & "<br>" & vbCrLf
        Else
            On Error GoTo 0
            Response.Write "<pre>" & vbCrLf
            Do Until w_F.AtEndOfStream
                'ソースを読む
                w_TXT = w_F.ReadLine
                If Len(w_TXT & "") > 0 Then
                    '特殊文字を編集
                    w_TXT = Replace(w_TXT, "&", "&amp;")
                    w_TXT = Replace(w_TXT, """", "&quot;")
                    w_TXT = Replace(w_TXT, "<", "&lt;")
                    w_TXT = Replace(w_TXT, ">", "&gt;")
                End If
                Response.Write w_TXT & vbCrLf
            Loop
            Response.Write "</pre>" & vbCrLf
            'ソースファイルを閉じる
            w_F.Close
            Set w_F = Nothing
            Set w_FS = Nothing
        End If
    End If
End If
%>
</body>
</html>